Excel : des formules sur les dates

Rien de plus facile que de taper une date dans Excel mais comment calculer une date d’échéance, connaitre le n° de semaine, le nombre de jours d’un mois, la date du lundi,… ?

Quelques fonctions d’Excel et formules et le tour est joué. Dans toutes les fonctions indiquées ci dessous, nous considérons que la cellule B2 contient une date.

La date du jour : =AUJOURDHUI()

Les échéances :

• 30 jours net : =B2+30
• 30 jours fin de mois : =FIN.MOIS(B2;1)
  le 2ème paramètre de FIN.MOIS permet d’indiquer le nombre de mois décalé, ici 1 mois pour 30 jours.
• 30 jours fin de mois le 15 : =FIN.MOIS(B2;1)+15
  nous avons simplement rajouté 15 jours à la formule précédente
• 60 jours fin de mois le 10 : =FIN.MOIS(B2;2)+10
  Ici nous décalons de 2 mois (60 jours).

Nombre de jours du mois d’une date : =JOUR(FIN.MOIS(B2;0))
FIN.MOIS avec le paramètre 0 permet de récupérer le dernier jour du mois de la date indiquée.
La fonction JOUR renvoi le n° du jour d’une date. Ici nous somme le dernier jour du mois donc le N° du jour correspond au nombre de jours du mois.

Le n° de la semaine d’une date : =NO.SEMAINE(B2;2)
Le paramètre 2 indique que le 1er jour de la semaine est le lundi (1 pour le dimanche).
Attention ! la fonction NO.SEMAINE d’Excel 2010 renvoi le n° de la semaine selon la règle suivante : la semaine 1 est la semaine contenant le 1er janvier de l’année.

Hors en France, la règle (Norme ISO) indique que :

1. la semaine commence le lundi ;
2. les jours de chaque semaine sont numérotés de 1 pour le lundi, à 7 pour le dimanche ;
3. la semaine 1 est celle qui contient le premier jeudi de l'année.

Pour respecter cette règle, utilisez la formule suivante :
=ENT(MOD(ENT((B2-2)/7)+0,6;52+5/28))+1

Les lundi

• de la semaine : =B2-MOD(B2-2;7)
  MOD renvoi le reste d’une division
  Vous pouvez également récupérer le samedi, dimanche, … qui précède en utilisant respectivement 0 ou 1 ou … (jusque 6) à la place du 2 dans la formule.
• le 1er d’une année (indiquée en C15) :
  =DATE(C15;1;1)-MOD(DATE(C15;1;1)-2;7)+SI(ANNEE(DATE(C15;1;1)-MOD(DATE(C15;1;1)-2;7))=C15;0;7)
• le 1er du mois :
  =DATE(C15;1;1)-MOD(DATE(C15;1;1)-2;7)+SI(ANNEE(DATE(C15;1;1)-MOD(DATE(C15;1;1)-2;7))=C15;0;7)

Savoir si une année est bissextile : =JOUR(DATE(ANNEE(B2);3;0))=29
ANNEE(B2) renvoi l’année de la date en B2
DATE(année;mois;jour) renvoi une date à partir d’un n° d’année, d’un n° de mois et d’un n° du jour. DATE(ANNEE(B2);3;0) renvoi le jour 0 du mois de mars de l’année de la date en B2. Le jour 0 correspond au  dernier jour du mois précédent, ici le dernier jour du mois de février.
Il ne reste plus qu’à vérifier si le jour de cette date est égale à 29, dans ce cas l’année est bissextile.

Cathy MONIER, MVP Excel
Auteur du site CathyAstuce